File Coverage

blib/lib/App/bif/show/change.pm

Criterion	Covered	Total	%
statement	21	60	35.0
branch	0	10	0.0
condition	0	6	0.0
subroutine	7	7	100.0
pod	1	1	100.0
total	29	84	34.5

package App::bif::show::change;
use strict;
use warnings;
use App::bif::log;
use Bif::Mo;
use DBIx::ThinSQL qw/sq qv/;
use Encode;

our $VERSION = '0.1.5_7';
extends 'App::bif::show';

sub run {
    my $self  = shift;
    my $opts  = $self->opts;
    my $dbw   = $self->dbw;
    my $info  = $self->get_change( $opts->{uid} );
    my $now   = $self->now;
    my $devel = eval { require YAML::Tiny };

    my $ref = $dbw->xhashref(
        select => [
            'c.id',
            'c.mtime AS mtime',
            'c.mtimetz AS mtimetz',
            'c.mtimetzhm AS mtimetzhm',
            "$now - c.mtime AS mtime_age",
            'c.uuid AS uuid',
            'c.action',
            'e.name',
            'COALESCE(c.author,e.name) AS author',
            'COALESCE(c.author_contact,ecm.mvalue) AS contact',
            'c.message',
        ],
        from       => 'changes c',
        inner_join => 'identities id',
        on         => 'id.id = c.identity_id',
        inner_join => 'entities e',
        on         => 'e.id = c.identity_id',
        inner_join => 'entity_contact_methods ecm',
        on         => 'ecm.id = e.default_contact_method_id',
        left_join  => 'change_deltas cd',
        on         => 'cd.change_id = c.id',
        where      => { 'c.id' => $info->{id} },
    );

    # YAML::Tiny only installed by cpanm --with-develop
    my $yaml     = '';
    my $ref_uuid = $ref->{uuid};

    if ($devel) {
        require Bif::DB::Plugin::ChangeUUIDv1;
        require Digest::SHA;

        my $changeset = $dbw->uchangeset_v1( $info->{id} );

        my $begin = shift @$changeset;
        my $end   = pop @$changeset;
        my $uuid  = delete $end->{uuid};

        foreach my $x (@$changeset) {
            next
              unless ref $x eq 'HASH'
              && exists $x->{_delta}
              && $x->{_delta} =~ m/^new_/;
            delete $x->{uuid};
        }

        $yaml = YAML::Tiny::Dump( [ $begin, @$changeset, $end ] );

        my ( $green, $red, $reset ) = $self->colours(qw/green red reset/);

        $ref_uuid = $reset . $red . 'INVALID' . $reset
          unless Digest::SHA::sha1_hex( Encode::encode( 'UTF-8', $yaml ) ) eq
          $ref->{uuid};

        if ( $opts->{diff} ) {
            require Text::Diff;
            my $terms = $dbw->xval(
                select => 'c.yaml',
                from   => 'changes c',
                where  => { 'c.id' => $info->{id} },
            );

            my $diff =
              Text::Diff::diff( \$terms, \$yaml, { CONTEXT => length $yaml } );

            if ($diff) {
                $diff =~ s/^\-(.*)/$red-$1$reset/mg;
                $diff =~ s/^\+(.*)/$green+$1$reset/mg;
                $diff =~ s/.*//;
                $yaml = $diff;
            }
            else {
                $yaml =~ s/^/ /mg;
                $yaml = "\n" . $yaml;
            }
        }
        else {
            $yaml =~ s/^/ /mg;
            $yaml = "\n" . $yaml;
        }
    }
    else {
        $yaml = "Details only shown when developer libraries installed\n";
    }

    my @data;
    push( @data,
        $self->header( '  From',   $ref->{author}, $ref->{contact} ),
        $self->header( '  When',   $self->mtime_ago($ref) ),
        $self->header( '  Action', $ref->{action} ),
    );

    $self->start_pager;

    print $self->render_table( 'l  l',
        $self->header( 'change', $ref->{id}, $ref_uuid ),
        \@data, 1 ),
      $yaml;

    return $self->ok('ShowChange');
}

1;
__END__