File Coverage

blib/lib/App/bif/pull/hub.pm

Criterion	Covered	Total	%
statement	10	12	83.3
branch			n/a
condition			n/a
subroutine	4	4	100.0
pod			n/a
total	14	16	87.5

package App::bif::pull::hub;
use strict;
use warnings;
use AnyEvent;
use Bif::Sync::Client;
use Bif::Mo;
use Coro;
use DBIx::ThinSQL qw/qv/;
use Log::Any '$log';
use Path::Tiny;

our $VERSION = '0.1.5_7';
extends 'App::bif';

sub run {
    my $self = shift;
    my $opts = $self->opts;

    # Do this early so that we complain about missing repo before we
    # complain about a missing hub
    my $dbw = $self->dbw;    # Consider upping PRAGMA cache_size?
                             #Or handle that in Bif::Role::Sync?

    if ( $opts->{location} =~ m!^(ssh://)?(.*)@(.*)! ) {
        $opts->{name} = $2;
    }
    elsif ( -d $opts->{location} ) {
        $opts->{location} = path( $opts->{location} )->realpath;
        $opts->{name}     = $opts->{location}->basename;
    }
    else {
        return $self->err( 'HubNotFound', 'hub not found: %s',
            $opts->{location} );
    }

    $log->debug("pull hub: $opts->{location}");
    if ( my $hub = $self->dbw->get_hub( $self->uuid2id( $opts->{location} ) ) )
    {
        warn "warning: hub already exists: $hub->{name}\n";
    }

    $|++;    # no buffering
    my $error;
    my $cv = AE::cv;

    my $client = Bif::Sync::Client->new(
        name          => $opts->{name},
        db            => $dbw,
        location      => $opts->{location},
        debug         => $opts->{debug},
        debug_bifsync => $opts->{debug_bifsync},
        on_update     => sub {
            my $client = shift;
            $self->lprint( $client->name . ': ' . $_[0] );
        },
        on_error => sub {
            $error = shift;
            $cv->send;
        },
    );

    my $fh   = select;
    my $coro = async {
        select $fh;

        eval {
            $dbw->txn(
                sub {
                    my ( $status, $ref ) = $client->pull_hub;

                    print "\n";

                    $client->disconnect;

                    if ( $status ne 'RepoImported' ) {
                        $error = $status;
                        $dbw->rollback;
                        return $status;
                    }

                    $dbw->xdo(
                        insert_or_replace_into =>
                          [ 'bifkv', qw/key change_id change_id2/ ],
                        select =>
                          [ qv('last_sync'), 'MAX(c.id)', 'MAX(c.id)', ],
                        from => 'changes c',
                    );

                    return $status;
                }
            );
        };

        if ($@) {
            $error = $@;
            print "\n";
        }

        return $cv->send;
    };

    $cv->recv;
    $client->disconnect;
    return $self->err( 'Unknown', $error ) if $error;
    return $self->ok('PullHub');

}

1;
__END__