File Coverage

blib/lib/App/bif/Editor.pm

Criterion	Covered	Total	%
statement	31	51	60.7
branch	4	22	18.1
condition	1	6	16.6
subroutine	12	13	92.3
pod	3	4	75.0
total	51	96	53.1

package App::bif::Editor;
use strict;
use warnings;
use Bif::Mo;
use Carp            ();
use File::Which     ();
use Path::Tiny      ();
use Proc::FastSpawn ();

our @CARP_NOT = (__PACKAGE__);

has auto => (
    is      => 'ro',
    default => 1,
);

has txt => ( is => 'rw', );

has encoding => (
    is      => 'ro',
    default => ':utf8',
);

has filename => (
    is      => 'rw',
    default => sub { Path::Tiny->tempfile },
);

has editor => (
    is      => 'ro',
    default => \&_build_editor,
);

has pid => ( is => 'rw', );

sub _build_editor {
    my $self = shift;

    if ( exists $ENV{EDITOR} ) {

        # Explicit editor defined
        return File::Which::which( $ENV{EDITOR} )
          || Carp::croak("editor not found: $ENV{EDITOR}");
    }

    # Otherwise take the first from our own list
    foreach my $editor (qw/sensible-editor vim vi emacs nano/) {
        my $path = File::Which::which($editor);
        return $path if $path;
    }

    Carp::croak("no suitable editor found");
}

sub BUILD {
    my $self = shift;
    $self->edit if $self->auto;
}

sub edit {
    my $self = shift;
    return if $self->pid or !-t STDOUT;

    $self->filename->spew( { binmode => $self->encoding }, $self->txt )
      if $self->txt;

    $self->pid(
        Proc::FastSpawn::spawn(
            $self->editor, [ $self->editor, $self->filename ]
        )
    );

    return;
}

sub wait_child {
    my $self = shift;
    return unless $self->pid;

    waitpid( $self->pid, 0 );
    $self->pid(undef);

    my $res = $?;
    my $err = $!;

    if ( $res == -1 ) {
        Carp::croak sprintf "%s failed to execute: %s", $self->editor, $err;
    }
    elsif ( $res & 127 ) {
        Carp::croak sprintf(
            "%s died with signal %d, %s coredump",
            $self->editor,
            ( $res & 127 ),
            ( ( $res & 128 ) ? 'with' : 'without' )
        );
    }
    elsif ( my $code = $res >> 8 ) {
        Carp::croak sprintf( "%s exited with code %d", $self->editor, $code );
    }
}

sub result {
    my $self = shift;
    return $self->txt unless -t STDOUT;
    $self->wait_child;

    return $self->filename->slurp( { binmode => $self->encoding } );
}

sub DESTROY {
    my $self = shift;
    $self->wait_child;
}

1;

__END__