File Coverage

blib/lib/App/bif/show/project.pm

Criterion	Covered	Total	%
statement	12	40	30.0
branch	0	12	0.0
condition			n/a
subroutine	4	4	100.0
pod	1	1	100.0
total	17	57	29.8

package App::bif::show::project;
use strict;
use warnings;
use Bif::Mo;

our $VERSION = '0.1.5_5';
extends 'App::bif::show';

sub run {
    my $self = shift;
    my $opts = $self->opts;
    my $db   = $self->db;
    my $info = $self->get_project( $opts->{id} ? $opts->{id} : $opts->{path} );
    my $now  = $self->now;

    my @data;

    DBIx::ThinSQL->import(qw/sum case coalesce concat qv/);

    my $ref = $db->xhashref(
        select => [
            'nodes.id',
            'substr(nodes.uuid,1,8) as uuid',
            'nodes.path',
            'projects.title',
            'nodes.ctime AS ctime',
            'nodes.ctimetz AS ctimetz',
            'nodes.ctimetzhm AS ctimetzhm',
            "$now - nodes.ctime AS ctime_age",
            'nodes.mtime AS mtime',
            'nodes.mtimetz AS mtimetz',
            'nodes.mtimetzhm AS mtimetzhm',
            "$now - nodes.mtime AS mtime_age",
            'changes.author',
            'changes.author_contact AS contact',
            'changes.message',
            'project_status.status',
            'project_status.status',
            'projects.local',
            'hn.name AS hub',
            'hn.uuid AS hub_uuid',
            'h.location',
        ],
        from       => 'projects',
        inner_join => 'nodes',
        on         => 'nodes.id = projects.id',
        inner_join => 'changes',
        on         => 'changes.id = nodes.first_change_id',
        inner_join => 'project_status',
        on         => 'project_status.id = projects.project_status_id',
        left_join  => 'nodes hn',
        on         => 'hn.id = projects.default_hub_id',
        left_join  => 'hubs h',
        on         => 'h.id = projects.default_hub_id',
        where      => { 'projects.id' => $info->{id} },
    );

    push( @data, $self->header( '  Path', $ref->{path}, $ref->{uuid} ), );
    push( @data, $self->header( '  Hub',  $ref->{hub},  $ref->{location} ), )
      if $ref->{hub};

    if ( $opts->{full} ) {
        push( @data,
            $self->header( '  Creator', $ref->{author}, $ref->{contact} ),
            $self->header( '  Created', $self->ctime_ago($ref) ),
        );
    }

    my @phases = $db->xarrayrefs(
        select => [
            case (
                when => { status => $ref->{status} },
                then => 'UPPER(status)',
                else => 'status',
            )->as('status'),
        ],
        from     => 'project_status',
        where    => { project_id => $info->{id} },
        order_by => 'rank',
    );

    push( @data,
        $self->header( '  Phases', join( ', ', map { $_->[0] } @phases ) ),
    );

    if ( $ref->{local} ) {
        my ( $ai, $si, $ri, $ii ) = $db->xlist(
            select => [
                coalesce( sum( { 'ist.status' => 'open' } ),    0 )->as('open'),
                coalesce( sum( { 'ist.status' => 'stalled' } ), 0 )
                  ->as('stalled'),
                coalesce( sum( { 'ist.status' => 'closed' } ), 0 )
                  ->as('closed'),
                coalesce( sum( { 'ist.status' => 'ignored' } ), 0 )
                  ->as('ignored'),
            ],
            from       => 'issue_status ist',
            inner_join => 'issues i',
            on         => 'i.issue_status_id = ist.id',
            where      => { 'ist.project_id' => $info->{id} },
        );

        my ( $at, $st, $rt, $it ) = $db->xlist(
            select => [
                coalesce( sum( { status => 'open' } ),    0 )->as('open'),
                coalesce( sum( { status => 'stalled' } ), 0 )->as('stalled'),
                coalesce( sum( { status => 'closed' } ),  0 )->as('closed'),
                coalesce( sum( { status => 'ignored' } ), 0 )->as('ignored'),
            ],
            from       => 'task_status',
            inner_join => 'tasks',
            on         => 'tasks.task_status_id = task_status.id',
            where      => { 'task_status.project_id' => $info->{id} },
        );

        my $total_issues = $ai + $si + $ri;
        my $total_tasks  = $at + $st + $rt;
        my $total        = $total_issues + $total_tasks;
        my $progress     = $total ? int( ( ( $ri + $rt ) / $total ) * 100 ) : 0;

        push(
            @data,
            $self->header( '  Progress', $progress . '%' ),
            $self->header(
                '  Tasks', "$at open, $st stalled, $rt closed, $it ignored"
            ),

            # TODO "Updated:..."
            $self->header(
                '  Issues', "$ai open, $si stalled, $ri closed, $ii ignored"
            ),

            # TODO "Updated:..."
            $self->header( '  Updated', $self->mtime_ago($ref) ),
        );
    }

    if ( $opts->{full} ) {
        require Text::Autoformat;
        push(
            @data,
            $self->header(
                'Description',
                Text::Autoformat::autoformat(
                    $ref->{message},
                    {
                        right => 60,
                        all   => 1
                    }
                )
            ),
        );
    }
    $self->start_pager;
    print $self->render_table( 'l  l', [ 'Project', $ref->{title} ], \@data,
        1 );

    print "\n";
    $self->dispatch( 'App::bif::log::project',
        { opts => { path => $info->{path} } } );

    return $self->ok( 'ShowProject', \@data );
}

1;
__END__