File Coverage

blib/lib/App/bif/new/repo.pm

Criterion	Covered	Total	%
statement	54	54	100.0
branch	9	10	90.0
condition			n/a
subroutine	9	9	100.0
pod	1	1	100.0
total	73	74	98.6

package App::bif::new::repo;
use strict;
use warnings;
use Bif::Mo;
use Bif::DBW;
use Config::Tiny;
use Log::Any '$log';
use Path::Tiny qw/path tempdir/;

our $VERSION = '0.1.5_5';
extends 'App::bif';

has subref => ( is => 'ro', );

sub run {
    my $self = shift;
    my $opts = $self->opts;

    return $self->err( 'DirExists', 'location exists: ' . $opts->{directory} )
      if -e $opts->{directory};

    $opts->{directory} = path( $opts->{directory} );
    $opts->{directory}->parent->mkpath;

    my $tempdir = tempdir(
        CLEANUP  => !$opts->{debug},
        DIR      => $opts->{directory}->parent,
        TEMPLATE => 'bif-new-repo-XXXXXX',
    );
    $log->debug( 'init: tmpdir ' . $tempdir );

    $self->repo($tempdir);

    # Fake App::bif into thinking the database already exists
    $tempdir->child( $self->dbfile( $self->DBVERSION ) )->touch;
    my $dbw = $self->dbw;

    # On windows at least, an SQLite handle on the database prevents a
    # rename or temp directory removal. Unfortunately, doing the
    # eval/disconnect check below results in the "uncleared implementors
    # data" warning on error. For the moment I would prefer the warning
    # than have the user left with a temporary directory to clean up.

    eval {
        $dbw->txn(
            sub {
                $|++;
                printf "Creating repository: %s ", $opts->{directory};

                my ( $old, $new ) = $dbw->deploy( $self->DBVERSION );
                printf "(v%d.%d)\n", $self->DBVERSION, $new;

                $self->subref->( $self, $self->DBVERSION, $new )
                  if $self->subref;
            }
        );
    };

    if ( my $err = $@ ) {
        $dbw->disconnect;
        Carp::croak $err;
    }
    $dbw->disconnect;

    if ( $opts->{config} ) {
        my $conf = Config::Tiny->new;

        $conf->{'user.alias'}->{ls} =
          'list topics --status open --project-status run';
        $conf->{'user.alias'}->{lss} =
          'list topics --status open --status stalled --project-status run';
        $conf->{'user.alias'}->{l}   = 'list projects define plan run';
        $conf->{'user.alias'}->{lsi} = 'list identities';

        $conf->write( $tempdir->child('config') );
    }

    # Mark this as a repo for convenience
    $tempdir->child('.bif')->touch;

    $tempdir->move( $opts->{directory} )
      || return $self->err( 'Rename',
        "rename $tempdir $opts->{directory}: $!" );

    # Rebuild the dbw for further commands?
    $self->repo( $opts->{directory} );
    $self->dbw( $self->_build_dbw );

    return $self->ok('NewRepo');
}

1;
__END__