File Coverage

blib/lib/App/bif/new/identity.pm

Criterion	Covered	Total	%
statement	58	58	100.0
branch	4	4	100.0
condition	16	28	57.1
subroutine	9	9	100.0
pod	1	1	100.0
total	88	100	88.0

package App::bif::new::identity;
use strict;
use warnings;
use Bif::Mo;
use Config::Tiny;
use DBIx::ThinSQL qw/bv/;
use IO::Prompt::Tiny qw/prompt/;
use Path::Tiny qw/path/;

our $VERSION = '0.1.5_5';
extends 'App::bif';

sub run {
    my $self = shift;
    my $opts = $self->opts;
    my $dbw  = $self->dbw;

    $dbw->txn(
        sub {
            my $start = time;
            $self->stop_work(
                stop => $start,
                save => 1,
            );

            my $name   = '';
            my $email  = '';
            my $spacer = '';

            if ( $opts->{self} ) {
                print "Creating \"self\" identity:\n";

                my $git_conf_file =
                  path( File::HomeDir->my_home, '.gitconfig' );
                my $git_conf = Config::Tiny->read($git_conf_file) || {};

                $name  = $git_conf->{user}->{name}  || 'Your Name';
                $email = $git_conf->{user}->{email} || '[e-mail]';

                $name =~ s/(^")|("$)//g;
                $email =~ s/(^")|("$)//g;

                $spacer = '  ';
            }

            $opts->{name} ||= prompt( $spacer . 'Name:', $name )
              || return $self->err( 'NameRequired', 'name is required' );

            my $short = join( '', $opts->{name} =~ m/(\b\w)/g );
            $opts->{shortname} ||= prompt( $spacer . 'Short Name:', $short )
              || return $self->err( 'NameRequired', 'shortname is required' );

            $opts->{method} ||= prompt( $spacer . 'Contact Method:', 'email' )
              || return $self->err( 'MethodRequired', 'method is required' );

            $opts->{value} ||=
              prompt( $spacer . 'Contact ' . ucfirst( $opts->{method} ) . ':',
                $email )
              || return $self->err( 'ValueRequired', 'value is required' );

            $opts->{message} ||= '';
            $opts->{id}     = $dbw->nextval('nodes');
            $opts->{ecm_id} = $dbw->nextval('nodes');

            if ( $opts->{self} ) {
                $opts->{change_id} = $self->new_change(
                    author         => $opts->{name},
                    author_contact => bv( $opts->{value}, DBI::SQL_VARCHAR ),
                    author_contact_method => $opts->{method},
                    author_shortname      => $opts->{shortname},
                );
            }
            else {
                $opts->{change_id} = $self->new_change();
            }

            $dbw->xdo(
                insert_into => 'func_new_identity',
                values      => {
                    id        => $opts->{id},
                    change_id => $opts->{change_id},
                    name      => $opts->{name},
                    shortname => $opts->{shortname},
                    self      => $opts->{self},
                },
            );

            $dbw->xdo(
                insert_into => 'func_new_identity_contact_method',
                values      => {
                    change_id   => $opts->{change_id},
                    id          => $opts->{ecm_id},
                    identity_id => $opts->{id},
                    method      => $opts->{method},
                    mvalue      => bv( $opts->{value}, DBI::SQL_VARCHAR ),
                },
            );

            $dbw->xdo(
                insert_into => 'func_update_identity',
                values      => {
                    change_id                 => $opts->{change_id},
                    id                        => $opts->{id},
                    contact_id                => $opts->{id},
                    default_contact_method_id => $opts->{ecm_id},
                },
            );

            $self->start_work(
                node_id       => $opts->{id},
                start         => $start,
                start_comment => "new identity",
                billable      => 1,
            );

            $self->stop_work(
                stop    => time,
                restore => 1,
            );

            $self->save_work(
                node_id   => $opts->{id},
                change_id => $opts->{change_id}
            );

            $self->end_change(
                id            => $opts->{change_id},
                message       => $opts->{message},
                action_format => "new identity %s "
                  . "$opts->{name} ($opts->{shortname})",
                action_node_id_1 => $opts->{id},
            );
        }
    );

    return $self->ok('NewIdentity');
}

1;
__END__