File Coverage

blib/lib/App/Stow/Check.pm

Criterion	Covered	Total	%
statement	21	54	38.8
branch	0	12	0.0
condition	0	9	0.0
subroutine	7	10	70.0
pod	2	2	100.0
total	30	87	34.4

package App::Stow::Check;

use strict;
use warnings;

use Cwd qw(realpath);
use File::Spec::Functions qw(abs2rel splitdir);
use File::Which qw(which);
use Getopt::Std;
use Readonly;

Readonly::Scalar our $DEFAULT_STOW_DIR => '/usr/local/stow';

our $VERSION = 0.02;

# Constructor.
sub new {
	my ($class, @params) = @_;

	# Create object.
	my $self = bless {}, $class;

	# Object.
	return $self;
}

# Run.
sub run {
	my $self = shift;

	# Process arguments.
	$self->{'_opts'} = {
		'd' => $DEFAULT_STOW_DIR,
		'h' => 0,
	};
	if (! getopts('d:h', $self->{'_opts'}) || $self->{'_opts'}->{'h'} || @ARGV < 1) {
		print STDERR "Usage: $0 [-d stow_dir] [-h] [--version] command\n";
		print STDERR "\t-d stow_dir\tStow directory (default value is '$DEFAULT_STOW_DIR').\n";
		print STDERR "\t-h\t\tHelp.\n";
		print STDERR "\t--version\tPrint version.\n";
		print STDERR "\tcommand\t\tCommand for which is stow dist looking.\n";
		return 1;
	}
	$self->{'_command'} = $ARGV[0];

	my ($exit_code, $message) = $self->_check;
	if ($exit_code == 0) {
		print $message."\n";
	} else {
		print STDERR $message."\n";
	}

	return $exit_code;
}

sub _check {
	my $self = shift;

	my $command = $self->{'_command'};

	my $command_path = which($command);
	if (! defined $command_path) {
		return (1, "Command '$command' not found.");
	}

	my $stow_dir = $self->{'_opts'}->{'d'};
	if (! -d $stow_dir) {
		return (1, "Stow directory '$stow_dir' doesn't exist.");
	}
	my $rel_path = abs2rel(realpath($command_path), $stow_dir);
	my @rel_path = splitdir($rel_path);
	if ($rel_path[0] eq '..') {
		return (1, "Command '$command' doesn't use stow.");
	}
	if ($rel_path[1] ne 'bin' && $rel_path[1] ne 'sbin') {
		return (1, "Command '$command' don't use 'bin/sbin' path.");
	}

	return (0, $rel_path[0]);
}

1;


__END__