File Coverage

blib/lib/App/Slackeria/Output.pm

Criterion	Covered	Total	%
statement	18	52	34.6
branch	0	10	0.0
condition	0	17	0.0
subroutine	6	8	75.0
pod	1	2	50.0
total	25	89	28.0

package App::Slackeria::Output;
use strict;
use warnings;
use autodie;
use 5.010;

use File::ShareDir qw(dist_file);
use HTML::Template;

our $VERSION = '0.12';

sub format_check {
	my ( $self, $res ) = @_;
	my ( $class, $href, $data );

	if ( not $res->{skip} and $res->{ok} and $res->{data} eq q{} ) {
		$data = 'ok';
	}

	if ( $res->{ok} and $res->{href} ) {
		$href = $res->{href};
	}

	if ( not $res->{skip} ) {
		$data //= $res->{data};
		if ( $res->{ok} ) {
			$class = 'ok';
		}
		else {
			$class = 'fail';
		}
	}

	return {
		class => $class // q{},
		data  => $data,
		href  => $href,
	};
}

sub write_out {
	my ( $self, %opt ) = @_;
	my @project_lines;
	my @headers;

	my $filename = $opt{filename};
	my $project  = $opt{data};
	my $template = $opt{template}
	  // dist_file( 'App-Slackeria', 'template.xhtml' );

	my $tmpl = HTML::Template->new( filename => $template );

	$tmpl->param(
		title   => 'Software version matrix',
		version => $VERSION,
	);

	for my $p ( sort keys %{$project} ) {

		my @plugins = sort keys %{ $project->{$p} };

		my @project_plugins
		  = map { $self->format_check( $project->{$p}->{$_} ) } @plugins;

		if ( @headers == 0 ) {
			push( @headers, map { { plugin => $_ } } @plugins );
		}

		push(
			@project_lines,
			{
				project => $p,
				plugins => [@project_plugins]
			}
		);

	}

	$tmpl->param(
		headers  => [@headers],
		projects => [@project_lines],
	);

	open( my $fh, '>', $filename );
	print $fh $tmpl->output();
	close($fh);

	return;
}

1;

__END__