File Coverage

lib/App/Sandy/WeightedRaffle.pm

Criterion	Covered	Total	%
statement	32	34	94.1
branch	6	8	75.0
condition	3	3	100.0
subroutine	7	7	100.0
pod	0	2	0.0
total	48	54	88.8

package App::Sandy::WeightedRaffle;
# ABSTRACT: Weighted raffle interface.

use App::Sandy::Base 'class';

with 'App::Sandy::Role::BSearch';

our $VERSION = '0.25'; # VERSION

has 'keys' => (
	traits     => ['Array'],
	is         => 'ro',
	isa        => 'ArrayRef',
	required   => 1,
	handles    => { _get_key => 'get' }
);

has 'weights' => (
	is         => 'ro',
	isa        => 'ArrayRef[My:IntGt0]',
	required   => 1
);

has '_weights' => (
	is         => 'ro',
	isa        => 'My:Weights',
	builder    => '_build_weights',
	lazy_build => 1
);

has '_num_weights' => (
	is         => 'ro',
	isa        => 'My:IntGt0',
	builder    => '_build_num_weights',
	lazy_build => 1
);

has '_max_weight' => (
	is         => 'ro',
	isa        => 'My:IntGe0',
	builder    => '_build_max_weight',
	lazy_build => 1
);

sub BUILD {
	my $self = shift;

	my $weights = $self->weights;
	my $keys = $self->keys;

	if (scalar(@$weights) != scalar(@$keys)) {
		croak "Number of weights must be equal to the number of keys";
	}
}

sub _build_num_weights {
	my $self = shift;
	my $weights = $self->_weights;
	return scalar @$weights;
}

sub _build_max_weight {
	my $self = shift;
	my $weights = $self->_weights;
	return $weights->[-1]{up};
}

sub _build_weights {
	my $self = shift;
	my $weights = $self->weights;

	my @weights_offset;
	my $left = 0;

	for (my $i = 0; $i < @$weights; $i++) {
		my %weight = (
			down => $left,
			up   => $left + $weights->[$i] - 1
		);

		$left += $weights->[$i];
		push @weights_offset => \%weight;
	}

	return \@weights_offset;
}

sub weighted_raffle {
	my ($self, $rng) = @_;

	# Raffle between 0 and max weight
	my $range = $rng->get_n($self->_max_weight + 1);

	# Look for the index where the range is
	my $index = $self->with_bsearch($range, $self->_weights,
		$self->_num_weights, \&_cmp);

	if (not defined $index) {
		croak "Random index not found at range = $range";
	}

	# Do it!
	return $self->_get_key($index);
}

sub _cmp {
	# State the function to compare at bsearch
	my ($range, $weight) = @_;

	if ($range >= $weight->{down} && $range <= $weight->{up}) {
		return 0;
	}
	elsif ($range > $weight->{down}) {
		return 1;
	} else {
		return -1;
	}
}

__END__

=pod

=encoding UTF-8

=head1 NAME

App::Sandy::WeightedRaffle - Weighted raffle interface.

=head1 VERSION

version 0.25

=head1 AUTHORS

=over 4

=item *

Thiago L. A. Miller <[e-mail]>

=item *

J. Leonel Buzzo <[e-mail]>

=item *

Felipe R. C. dos Santos <[e-mail]>

=item *

Helena B. Conceição <[e-mail]>

=item *

Rodrigo Barreiro <[e-mail]>

=item *

Gabriela Guardia <[e-mail]>

=item *

Fernanda Orpinelli <[e-mail]>

=item *

Rafael Mercuri <[e-mail]>

=item *

Rodrigo Barreiro <[e-mail]>

=item *

Pedro A. F. Galante <[e-mail]>

=back

=head1 COPYRIGHT AND LICENSE

This software is Copyright (c) 2023 by Teaching and Research Institute from Sírio-Libanês Hospital.

This is free software, licensed under:

  The GNU General Public License, Version 3, June 2007

=cut