File Coverage

blib/lib/App/RL/Command/genome.pm

Criterion	Covered	Total	%
statement	49	51	96.0
branch	7	10	70.0
condition			n/a
subroutine	11	11	100.0
pod	6	6	100.0
total	73	78	93.5

package App::RL::Command::genome;
use strict;
use warnings;
use autodie;

use App::RL -command;
use App::RL::Common;

sub abstract {
    return 'convert chr.size to whole genome runlists';
}

sub opt_spec {
    return (
        [ "outfile|o=s", "output filename. [stdout] for screen" ],
        [ "remove|r",    "remove 'chr0' from chromosome names" ],
        { show_defaults => 1, }
    );
}

sub usage_desc {
    return "runlist genome [options] ";
}

sub description {
    my $desc;
    $desc .= ucfirst(abstract) . ".\n";
    return $desc;
}

sub validate_args {
    my ( $self, $opt, $args ) = @_;

    if ( @{$args} != 1 ) {
        my $message = "This command need one input file.\n\tIt found";
        $message .= sprintf " [%s]", $_ for @{$args};
        $message .= ".\n";
        $self->usage_error($message);
    }
    for ( @{$args} ) {
        next if lc $_ eq "stdin";
        if ( !Path::Tiny::path($_)->is_file ) {
            $self->usage_error("The input file [$_] doesn't exist.");
        }
    }

    if ( !exists $opt->{outfile} ) {
        $opt->{outfile} = Path::Tiny::path( $args->[0] )->absolute . ".yml";
    }
}

sub execute {
    my ( $self, $opt, $args ) = @_;

    #----------------------------#
    # Loading
    #----------------------------#
    my $length_of = App::RL::Common::read_sizes( $args->[0], $opt->{remove} );

    #----------------------------#
    # Operating
    #----------------------------#
    my $r_of = {};
    for my $key ( keys %{$length_of} ) {
        my $set = App::RL::Common::new_set();
        $set->add_pair( 1, $length_of->{$key} );
        $r_of->{$key} = $set->runlist;
    }

    #----------------------------#
    # Output
    #----------------------------#
    my $out_fh;
    if ( lc( $opt->{outfile} ) eq "stdout" ) {
        $out_fh = *STDOUT;
    }
    else {
        open $out_fh, ">", $opt->{outfile};
    }
    print {$out_fh} YAML::Syck::Dump($r_of);

    close $out_fh;
}

1;