File Coverage

blib/lib/App/ape/update.pm

Criterion	Covered	Total	%
statement	51	51	100.0
branch	9	12	75.0
condition	2	2	100.0
subroutine	7	7	100.0
pod	2	2	100.0
total	71	74	95.9

# ABSTRACT: Associate Test results with a tracked defect
# PODNAME: App::ape::update

package App::ape::update;
$App::ape::update::VERSION = '0.001';
use strict;
use warnings;

use Getopt::Long qw{GetOptionsFromArray};
use App::Prove::Elasticsearch::Utils;
use Pod::Usage;

sub new {
    my ($class, @args) = @_;

    my (%options, @conf, $help);
    GetOptionsFromArray(
        \@args,
        'defect=s@'    => \$options{defects},
        'platform=s@'  => \$options{platforms},
        'version=s@'   => \$options{versions},
        'configure=s@' => \@conf,
        'status=s'     => \$options{status},
        'help'         => \$help
    );

    $options{defects} //= [];

    #Deliberately exiting here, as I "unit" test this as the binary
    pod2usage(0) if $help;

    if (!scalar(@args)) {
        pod2usage(
            -exitval => "NOEXIT",
            -msg => "Insufficient arguments.  You must pass at least one test.",
        );
        return 1;
    }

    if (!scalar(@{$options{defects}})) {
        pod2usage(
            -exitval => "NOEXIT",
            -msg =>
              "Insufficient arguments.  You must pass at least one defect.",
        );
        return 4;
    }

    my $conf = App::Prove::Elasticsearch::Utils::process_configuration(@conf);

    if (
        scalar(
            grep {
                my $subj = $_;
                grep { $subj eq $_ } qw{server.host server.port}
            } keys(%$conf)
        ) != 2
      ) {
        pod2usage(
            -exitval => "NOEXIT",
            -msg =>
              "Insufficient information provided to associate defect with test results to elasticsearch",
        );
        return 3;
    }

    my $self = {options => \%options, cases => \@args};

    $self->{indexer} = App::Prove::Elasticsearch::Utils::require_indexer($conf);
    &{\&{$self->{indexer} . "::check_index"}}($conf);

    return bless($self, $class);
}

sub run {
    my $self          = shift;
    my $global_result = 0;
    foreach my $case (@{$self->{cases}}) {
        $self->{options}{case} = $case;
        $global_result +=
          &{\&{$self->{indexer} . "::associate_case_with_result"}}
          (%{$self->{options}});
    }
    print "$global_result tests failed to be associated, examine above output\n"
      if $global_result;
    return $global_result ? 2 : 0;
}

1;

__END__