File Coverage

blib/lib/App/OverWatch.pm

Criterion	Covered	Total	%
statement	7	9	77.7
branch			n/a
condition			n/a
subroutine	3	3	100.0
pod			n/a
total	10	12	83.3

package App::OverWatch;

# ABSTRACT: Watch over your infrastructure
our $VERSION = '0.1'; # VERSION

use strict;
use warnings;

use App::OverWatch::DB;
use App::OverWatch::ServiceLock;
use App::OverWatch::EventLog;
use App::OverWatch::Notify;
use App::OverWatch::Config;

use Config::Tiny;

sub new {
    my $class = shift;
    my $rh_options = shift || {};

    my $self = bless( {}, $class );

    return $self;
}


sub servicelock {
    my $self = shift;

    if (!defined($self->{ServiceLock})) {
        $self->{ServiceLock} = App::OverWatch::ServiceLock->new({
            db => $self->_db()
        });
    }
    return $self->{ServiceLock};
}

sub notify {
    my $self = shift;

    if (!defined($self->{Notify})) {
        $self->{Notify} = App::OverWatch::Notify->new({
            db => $self->_db()
        });
    }
    return $self->{Notify};
}

sub eventlog {
    my $self = shift;

    if (!defined($self->{Eventlog})) {
        $self->{Eventlog} = App::OverWatch::Eventlog->new({
            db => $self->_db()
        });
    }
    return $self->{Eventlog};
}

sub check_options {
    my $self    = shift;
    my $rh_args = shift || {};

    my $ra_commands = $rh_args->{valid_commands};
    my $rh_options  = $rh_args->{options};
    my $rh_required = $rh_args->{required_options};

    ## Check that only one actual command was provided
    my $commands = join(', ', sort @$ra_commands);
    my @commands = map { $rh_options->{$_} ? $_ : () } @$ra_commands;
    die "Error: Please specify one and only one command ($commands)\n"
        if (scalar @commands != 1);

    my $command = $commands[0];

    ## Check all required options are defined
    for my $opt (@{ $rh_required->{$command} }) {
        die "Error: --$opt is a required option\n"
            if (!defined($rh_options->{$opt}));
    }

    return $command;
}

sub load_config {
    my $self = shift;
    my $path = shift;

    my $rh_conf;

    my @paths;
    if (defined($path)) {
        @paths = ( $path );
    } else {
        @paths = ( $ENV{HOME} . "/.overwatch.conf",
                       "/etc/overwatch.conf" );
    }

  FILE:
    for my $file (@paths) {
        next FILE
            if (!defined($file) || ! -f $file);

        my $Config = Config::Tiny->read($file);
        $rh_conf = $Config->{_}
            if ($Config && defined($Config->{_}));
    }

    die "Error: Couldn't load configuration from "
        . join(', ', @paths) . "\n"
            if (!defined($rh_conf));

    die "Error: Require 'db_type' to be set in config\n"
        if (!$rh_conf->{db_type});

    $self->{Config} = App::OverWatch::Config->new($rh_conf);
}

sub load_config_string {
    my $self = shift;
    my $string = shift;

    my $Config = Config::Tiny->read_string($string);
    my $rh_conf = $Config->{_}
        if ($Config && defined($Config->{_}));

    die "Error: Couldn't load configuration from string\n"
        if (!defined($rh_conf));

    die "Error: Require 'db_type' to be set in config\n"
        if (!$rh_conf->{db_type});

    $self->{Config} = App::OverWatch::Config->new($rh_conf);
}

sub _db {
    my $self = shift;

    if (!defined($self->{DB})) {
        $self->{DB} = App::OverWatch::DB->new( $self->{Config} );
    }
    return $self->{DB};
}

1;

__END__