File Coverage

blib/lib/App/MARC/Filter.pm

Criterion	Covered	Total	%
statement	93	95	97.8
branch	22	32	68.7
condition	4	6	66.6
subroutine	13	13	100.0
pod	2	2	100.0
total	134	148	90.5

package App::MARC::Filter;

use strict;
use warnings;

use Class::Utils qw(set_params);
use English;
use Error::Pure qw(err);
use Getopt::Std;
use List::MoreUtils qw(none);
use MARC::File::XML (BinaryEncoding => 'utf8', RecordFormat => 'MARC21');
use Readonly;
use Unicode::UTF8 qw(encode_utf8 decode_utf8);

Readonly::Array our @OUTPUT_FORMATS => qw(ascii xml);

our $VERSION = 0.01;

# Constructor.
sub new {
	my ($class, @params) = @_;

	# Create object.
	my $self = bless {}, $class;

	# Process parameters.
	set_params($self, @params);

	# Object.
	return $self;
}

# Run.
sub run {
	my $self = shift;

	# Process arguments.
	$self->{'_opts'} = {
		'h' => 0,
		'o' => 'xml',
		'r' => 0,
	};
	if (! getopts('ho:r', $self->{'_opts'}) || @ARGV < 4
		|| $self->{'_opts'}->{'h'}) {

		print STDERR "Usage: $0 [-h] [-o format] [-r] [--version] marc_xml_file field subfield value\n";
		print STDERR "\t-h\t\tPrint help.\n";
		print STDERR "\t-o format\tOutput MARC format. Possible formats are ascii, xml.\n";
		print STDERR "\t-r\t\tUse value as Perl regexp.\n";
		print STDERR "\t--version\tPrint version.\n";
		print STDERR "\tmarc_xml_file\tMARC XML file.\n";
		print STDERR "\tfield\t\tMARC field.\n";
		print STDERR "\tsubfield\tMARC subfield.\n";
		print STDERR "\tvalue\t\tMARC field/subfield value to filter.\n";
		return 1;
	}
	$self->{'_marc_xml_file'} = shift @ARGV;
	$self->{'_marc_field'} = shift @ARGV;
	$self->{'_marc_subfield'} = shift @ARGV;
	$self->{'_marc_value'} = decode_utf8(shift @ARGV);

	# Check output format.
	if (none { $self->{'_opts'}->{'o'} eq $_ } @OUTPUT_FORMATS) {
		err "Output format '$self->{'_opts'}->{'o'}' doesn't supported.";
	}

	my $marc_file = MARC::File::XML->in($self->{'_marc_xml_file'});
	my @ret;
	my $num = 1;
	my $previous_record;
	while (1) {
		my $record = eval {
			$marc_file->next;
		};
		if ($EVAL_ERROR) {
			print STDERR "Cannot process '$num' record. ".
				(
					defined $previous_record
					? "Previous record is ".encode_utf8($previous_record->title)."\n"
					: ''
				);
			print STDERR "Error: $EVAL_ERROR\n";
			next;
		}
		if (! defined $record) {
			last;
		}
		$previous_record = $record;

		my @fields = $record->field($self->{'_marc_field'});
		foreach my $field (@fields) {
			my @subfield_values = $field->subfield($self->{'_marc_subfield'});
			foreach my $subfield_value (@subfield_values) {
				if (defined $subfield_value) {
					my $match = 0;
					if ($self->{'_opts'}->{'r'}) {
						if ($subfield_value =~ m/$self->{'_marc_value'}/ms) {
							$match = 1;
						}
					} else {
						if ($subfield_value eq $self->{'_marc_value'}) {
							$match = 1;
						}
					}
					if ($match) {
						push @ret, $record;
					}
				}
			}
		}

		$num++;
	}

	# Print out.
	$num = 0;
	foreach my $ret (@ret) {
		if (! $num) {
			if ($self->{'_opts'}->{'o'} eq 'xml') {
				print MARC::File::XML::header()."\n";
			}
		}

		if ($self->{'_opts'}->{'o'} eq 'xml') {
			print encode_utf8(MARC::File::XML::record($ret))."\n";
		} elsif ($self->{'_opts'}->{'o'} eq 'ascii') {
			print encode_utf8($ret->as_formatted)."\n";
		}

		$num++;
	}
	if ($num) {
		if ($self->{'_opts'}->{'o'} eq 'xml') {
			print MARC::File::XML::footer()."\n";
		}
	}

	return 0;
}

1;


__END__