File Coverage

blib/lib/App/Kritika.pm

Criterion	Covered	Total	%
statement	39	39	100.0
branch	5	10	50.0
condition	1	3	33.3
subroutine	7	7	100.0
pod	0	2	0.0
total	52	61	85.2

package App::Kritika;

use strict;
use warnings;

our $VERSION = '0.03';

use JSON ();
use Cwd qw(abs_path);
use HTTP::Tiny;

sub new {
    my $class = shift;
    my (%params) = @_;

    my $self = {};
    bless $self, $class;

    $self->{base_url} = $params{base_url} or die 'base_url required';
    $self->{token}    = $params{token}    or die 'token required';
    $self->{root}     = $params{root};

    $self->{ua} = $params{ua} || HTTP::Tiny->new;

    return $self;
}

sub validate {
    my $self = shift;
    my ($path) = @_;

    $path = abs_path($path);

    my $content = do {
        local $/;
        open my $fh, '<', $path or die "Can't open file '$path': $!";
        <$fh>;
    };

    my $ua = $self->{ua};

    if (my $root = $self->{root}) {
        $root = abs_path($root);
        $path =~ s{^$root}{};
        $path =~ s{^/}{};
    }

    my $response = $ua->post_form(
        "$self->{base_url}/validate",
        {
            content => $content,
            path    => $path
        },
        {headers => {Authorization => 'Token ' . $self->{token}}}
    );

    die
"Remote error: $response->{status} $response->{reason}; $response->{content}\n"
      unless $response->{success};

    return JSON::decode_json($response->{content});
}

1;
__END__