File Coverage

blib/lib/App/JobLog/Command/last.pm

Criterion	Covered	Total	%
statement	59	60	98.3
branch	28	30	93.3
condition	3	3	100.0
subroutine	7	8	87.5
pod	3	4	75.0
total	100	105	95.2

package App::JobLog::Command::last;
$App::JobLog::Command::last::VERSION = '1.040';
# ABSTRACT: show details of last recorded event

use Modern::Perl;
use App::JobLog -command;
use Class::Autouse qw(
  App::JobLog::Log
  App::JobLog::Command::summary
);

sub execute {
   my ( $self, $opt, $args ) = @_;

   # construct event test
   my %must   = map { $_ => 1 } @{ $opt->tag     || [] };
   my %mustnt = map { $_ => 1 } @{ $opt->without || [] };
   my $test   = sub {
      my $event = shift;
      return if $event->is_note;
      my @tags  = @{ $event->tags };
      my %tags  = map { $_ => 1 } @tags;
      my $good  = 1;
      if (%must) {
         if ( $opt->any ) {
            $good = 0;
            for my $tag (@tags) {
               if ( $must{$tag} ) {
                  $good = 1;
                  last;
               }
            }
         }
         else {
            for my $tag ( keys %must ) {
               unless ( $tags{$tag} ) {
                  $good = 0;
                  last;
               }
            }
         }
      }
      if ( $good && %mustnt ) {
         if ( $opt->some ) {
            $good = 0;
            for my $tag ( keys %mustnt ) {
               unless ( $tags{$tag} ) {
                  $good = 1;
                  last;
               }
            }
         }
         else {
            for my $tag (@tags) {
               if ( $mustnt{$tag} ) {
                  $good = 0;
                  last;
               }
            }
         }
      }
      return $good;
   };

   # find event
   my ( $i, $count, $e ) = ( App::JobLog::Log->new->reverse_iterator, 0 );
   while ( $e = $i->() ) {
      $count++;
      last if $test->($e);
   }

   if ($e) {
      my $start = $e->start->strftime('%F at %H:%M:%S %p');
      my $end = $e->is_open ? 'now' : $e->end->strftime('%F at %H:%M:%S %p');
      $opt->{merge} = 'no_merge';
      App::JobLog::Command::summary->execute( $opt, ["$start - $end"] );
   }
   else {
      say $count ? 'no matching event' : 'empty log';
   }
}

sub usage_desc { '%c ' . __PACKAGE__->name }

sub abstract { 'describe the last task recorded' }

sub options {
   return (
      [
         'tag|t=s@',
         'find the last event with all of these tags; '
           . 'multiple tags may be specified'
      ],
      [ 'any|a', 'require only that one of the --tag tags be present' ],
      [
         'without|w=s@',
         'find the last event which does not have any of these tags; '
           . 'multiple tags may be specified'
      ],
      [
         'some|s', 'require only that some one of the --without tags be absent'
      ],
   );
}

1;

__END__