File Coverage

blib/lib/App/JobLog/Command/resume.pm

Criterion	Covered	Total	%
statement	12	68	17.6
branch	0	32	0.0
condition	0	3	0.0
subroutine	4	10	40.0
pod	3	5	60.0
total	19	118	16.1

package App::JobLog::Command::resume;
$App::JobLog::Command::resume::VERSION = '1.039';
# ABSTRACT: resume last closed task

use App::JobLog -command;
use Modern::Perl;
use Class::Autouse 'App::JobLog::Log';
use autouse 'App::JobLog::Time' => qw(now);

sub execute {
   my ( $self, $opt, $args ) = @_;

   # construct event test
   my %must   = map { $_ => 1 } @{ $opt->tag     || [] };
   my %mustnt = map { $_ => 1 } @{ $opt->without || [] };
   my $test   = sub {
      my $event = shift;
      my @tags  = @{ $event->tags };
      my %tags  = map { $_ => 1 } @tags;
      my $good  = 1;
      if (%must) {
         if ( $opt->any ) {
            $good = 0;
            for my $tag (@tags) {
               if ( $must{$tag} ) {
                  $good = 1;
                  last;
               }
            }
         }
         else {
            for my $tag ( keys %must ) {
               unless ( $tags{$tag} ) {
                  $good = 0;
                  last;
               }
            }
         }
      }
      if ( $good && %mustnt ) {
         if ( $opt->some ) {
            $good = 0;
            for my $tag ( keys %mustnt ) {
               unless ( $tags{$tag} ) {
                  $good = 1;
                  last;
               }
            }
         }
         else {
            for my $tag (@tags) {
               if ( $mustnt{$tag} ) {
                  $good = 0;
                  last;
               }
            }
         }
      }
      return $good;
   };

   # find event
   my $log = App::JobLog::Log->new;
   my ( $i, $count, $e ) = ( $log->reverse_iterator, 0 );
   while ( $e = $i->() ) {
      $count++;
      next unless $e->isa('App::JobLog::Log::Event');
      last if $test->($e);
   }

   $self->usage_error('empty log')         unless $count;
   $self->usage_error('no matching event') unless $e;
   $self->usage_error('event ongoing')     unless $e->is_closed;

   my $ll = $e->data->clone;
   $ll->time = now;
   $log->append_event($ll);
   print "resuming " . $e->describe;
   print ' (tags: ', join( ', ', sort $e->tag_list ), ')' if $e->tagged;
   print "\n";
}

sub usage_desc { '%c ' . __PACKAGE__->name . ' %o' }

sub abstract { 'resume last task' }

sub full_description {
   <
Starts a new task with an identical description and tags to the last
task in the log. If some restriction by tag is specified, it is the last
task with the given tags.
END
}

sub options {
   return (
      [
         'tag|t=s@',
         'resume the last event with all of these tags; '
           . 'multiple tags may be specified'
      ],
      [ 'any|a', 'require only that one of the --tag tags be present' ],
      [
         'without|w=s@',
         'resume the last event which does not have any of these tags; '
           . 'multiple tags may be specified'
      ],
      [
         'some|s', 'require only that some one of the --without tags be absent'
      ],
   );
}

1;

__END__