File Coverage

blib/lib/App/Image/Generator.pm

Criterion	Covered	Total	%
statement	40	59	67.8
branch	1	12	8.3
condition	2	6	33.3
subroutine	11	11	100.0
pod	2	2	100.0
total	56	90	62.2

package App::Image::Generator;

use strict;
use warnings;

use English;
use Error::Pure qw(err);
use File::Basename qw(fileparse);
use Getopt::Std;
use Image::Random;
use Image::Select;
use Readonly;

# Constants.
Readonly::Scalar our $EMPTY_STR => q{};

our $VERSION = 0.03;

# Constructor.
sub new {
	my $class = shift;

	# Create object.
	my $self = bless {}, $class;

	# Object.
	return $self;
}

# Run script.
sub run {
	my $self = shift;

	# Process arguments.
	$self->{'_opts'} = {
		'h' => 0,
		'i' => $EMPTY_STR,
		's' => '1920x1080',
		'v' => 0,
	};
	if (! getopts('hi:s:v', $self->{'_opts'}) || @ARGV < 1
		|| $self->{'_opts'}->{'h'}) {

		print STDERR "Usage: $0 [-h] [-i input_dir] [-s size] [-v]".
			"\n\t[--version] output_file\n\n";
		print STDERR "\t-h\t\tPrint help.\n";
		print STDERR "\t-i input_dir\tInput directory with ".
			"images (default value is nothing).\n";
		print STDERR "\t-s size\t\tSize (default value is ".
			"1920x1080).\n";
		print STDERR "\t-v\t\tVerbose mode.\n";
		print STDERR "\t--version\tPrint version.\n";

		return 1;
	}
	$self->{'_output_file'} = $ARGV[0];

	# Check size.
	if ($self->{'_opts'}->{'s'} !~ m/^(\d+)x(\d+)$/ms) {
		err 'Bad size value.', 'Value', $self->{'_opts'}->{'s'};
	}
	$self->{'_width'} = $1;
	$self->{'_height'} = $2;

	# Run.
	eval {
		my (undef, undef, $suffix) = fileparse($self->{'_output_file'},
			qr{\..*$});
		$suffix =~ s/^\.//g;
		my $type = lc($suffix);
		if ($type eq 'jpg') {
			$type = 'jpeg';
		}

		# Images from directory.
		my $ig;
		if ($self->{'_opts'}->{'i'} ne $EMPTY_STR) {
			$ig = Image::Select->new(
				'debug' => ($self->{'_opts'}->{'v'} ? 1 : 0),
				'height' => $self->{'_height'},
				'path_to_images' => $self->{'_opts'}->{'i'},
				'type' => $type,
				'width' => $self->{'_width'},
			);

		# Random image.
		} else {
			$ig = Image::Random->new(
				'height' => $self->{'_height'},
				'type' => $type,
				'width'=> $self->{'_width'},
			);
		}
		$ig->create($self->{'_output_file'});
	};
	if ($EVAL_ERROR) {
		err 'Cannot create image.';
	}

	return 0;
}

1;

__END__