File Coverage

blib/lib/App/Dex.pm

Criterion	Covered	Total	%
statement	38	50	76.0
branch	5	10	50.0
condition			n/a
subroutine	10	13	76.9
pod	0	3	0.0
total	53	76	69.7

package App::Dex;
use Moo;
use List::Util qw( first );
use YAML::PP qw( LoadFile );
use IPC::Run3;

our $VERSION = '0.002002';

has config_file => (
    is      => 'ro',
    isa     => sub { die 'Config file not found' unless $_[0] && -e $_[0] },
    lazy    => 1,
    default => sub {
        first { -e $_ } @{shift->config_file_names};
    },
);

has config_file_names => (
    is      => 'ro',
    lazy    => 1,
    default => sub {
        return [ qw( dex.yaml .dex.yaml ) ],
    },
);

has config => (
    is      => 'ro',
    lazy    => 1,
    builder => sub {
        LoadFile shift->config_file;
    },
);

has menu => (
    is      => 'ro',
    lazy    => 1,
    builder => sub {
        my ( $self ) = @_;
        return [ $self->_menu_data( $self->config, 0 ) ];
    }
);

sub _menu_data {
    my ( $self, $config, $depth ) = @_;

    my @menu;
    foreach my $block ( @{$config} ) {
        push @menu, {
            name  => $block->{name},
            desc  => $block->{desc},
            depth => $depth,
        };
        if ( $block->{children} ) {
            push @menu, $self->_menu_data($block->{children}, $depth + 1);

        }
    }
    return @menu;
}

sub display_menu {
    my ( $self, $menu ) = @_;

    $menu = $self->menu unless $menu;

    foreach my $item ( @{$menu} ) {
        printf( "%s%-24s: %s\n", " " x ( 4 * $item->{depth} ), $item->{name}, $item->{desc}  );
    }
}

sub resolve_block {
    my ( $self, $path ) = @_;

    return $self->_resolve_block( $path, $self->config );
}

sub _resolve_block {
    my ( $self, $path, $config ) = @_;

    my $block;
    while ( defined ( my $segment = shift @{$path} ) ) {
        $block = first { $_->{name} eq $segment } @{$config};

        return undef unless $block;

        if ( @{$path} ) {
            $config = $block->{children};
            next;
        }
    }
    return $block;
}

sub process_block {
    my ( $self, $block ) = @_;

    if ( $block->{shell} ) {
        _run_block_shell( $block );
    }
}

sub _run_block_shell {
    my ( $block ) = @_;

    foreach my $command ( @{$block->{shell}} ) {
        run3( $command );
    }
}

1;

__END__