File Coverage

blib/lib/App/Devmode2.pm

Criterion	Covered	Total	%
statement	21	101	20.7
branch	0	44	0.0
condition	0	12	0.0
subroutine	7	14	50.0
pod	4	4	100.0
total	32	175	18.2

package App::Devmode2;

# Created on: 2014-10-04 20:31:39
# Create by:  Ivan Wills
# $Id$
# $Revision$, $HeadURL$, $Date$
# $Revision$, $Source$, $Date$

use strict;
use warnings;
use English qw/ -no_match_vars /;
use Getopt::Long;
use FindBin qw/$Bin/;
use Path::Tiny;
use base qw/Exporter/;

our $VERSION = 0.9;
our ($name)  = $PROGRAM_NAME =~ m{^.*/(.*?)$}mxs;
our $tmux_conf    = path("$ENV{HOME}", '.tmux.conf');
our $tmux_layout  = path("$ENV{HOME}", '.tmux', 'layout');
our $tmux_devmode = path("$ENV{HOME}", '.tmux', 'devmode2');
our %option;
our %p2u_extra;

sub run {
    my ($self) = @_;
    Getopt::Long::Configure('bundling');
    my $success = GetOptions(
        \%option,
        'layout|l=s',
        'chdir|cd|c=s',
        'curdir|C',
        'save|s',
        'auto|auto-complete',
        'current=s',
        'test|t!',
        'verbose|v+',
        'man',
        'help',
        'version!',
    );

    if ( !$success && !$option{auto} ) {
        require Pod::Usage;
        Pod::Usage::pod2usage(
            -verbose => 1,
            -input   => __FILE__,
            %p2u_extra,
        );
        return 1;
    }
    elsif ( $option{'VERSION'} ) {
        print "$name Version = $VERSION\n";
        return 0;
    }
    elsif ( $option{'man'} ) {
        require Pod::Usage;
        Pod::Usage::pod2usage(
            -verbose => 2,
            -input   => __FILE__,
            %p2u_extra,
        );
        return 2;
    }
    elsif ( $option{'help'} ) {
        require Pod::Usage;
        Pod::Usage::pod2usage(
            -verbose => 1,
            -input   => __FILE__,
            %p2u_extra,
        );
        return 1;
    }
    elsif ( $option{auto} ) {
        $self->_auto();
        return 0;
    }

    # get the session name
    my $session  = @ARGV ? shift @ARGV : die "No session name passed!";
    my @sessions = $self->sessions();

    # set the terminal title to the session name
    $self->set_title($session);

    if ( grep { $_ eq $session } @sessions ) {
        # connect to session
        $self->_exec('tmux', '-u2', 'attach', '-t', $session);
        return 1;
    }

    # creating a new session should do some extra work
    $self->process_config($session, \%option);

    if ($option{chdir}) {
        die "No directory '$option{chdir}'!\n" if !-d $option{chdir};
        chdir $option{chdir};
    }

    my @actions = ('-u2', 'new-session', '-s', $session, ';', 'source-file', $tmux_conf);
    if ($option{layout}) {
        push @actions, ';', "source-file", $tmux_layout->child($option{layout});
    }

    $self->_exec('tmux', @actions);
    warn "Not found\n";

    return 1;
}

sub set_title {
    my ($self, $session) = @_;
    eval { require Term::Title; } or return;
    Term::Title::set_titlebar($session);
    return;
}

sub sessions {
    my $self = shift;
    return map {
            /^(.+) : \s+ \d+ \s+ window/xms;
            $1;
        }
        $self->_qx('tmux ls');
}

sub process_config {
    my ($self, $session, $option) = @_;
    my $config_file = $tmux_devmode->child($session);

    # return if no config and not saving
    return if !-f $config_file && !$option->{save};

    if ( -f $config_file ) {
        require YAML;
        my ($config) = YAML::LoadFile("$config_file");
        for my $key (keys %{ $config }) {
            $option->{$key} = $config->{$key} if !exists $option->{$key};
        }
    }

    # save the config if requested to
    if ($option->{save} || $option{curdir}) {
        # create the path if missing
        $config_file->parent->mkpath();

        # don't save saving
        delete $option->{save};

        if ($option{curdir}) {
            delete $option->{curdir};
            $option->{chdir} = path('.')->realpath . '';
        }

        # save the config to YAML
        require YAML;
        YAML::DumpFile("$config_file", $option);
    }

    return;
}

sub _qx {
    my $self = shift;
    return qx/@_/;
}

sub _exec {
    my $self = shift;
    print join ' ', @_, "\n" if $option{verbose};
    exec @_ if !$option{test};
    return;
}

sub _auto {
    my ($self) = @_;
    my $current  = $ARGV[$option{current}];
    my $previous = $ARGV[$option{current} - 1];

    if ( defined $current && $current =~ /^-/ ) {
        print join "\n", qw/-l --layout -s --save -c --cd -C --curdir/, '';
    }
    elsif ( $previous =~ /^-c$|^--(?:chdir|cd)$/ ) {
        print join "\n", glob "$current*";
    }
    else {
        my $dir = $previous =~ /^-\w*l$|^--layout$/ ? $tmux_layout : $tmux_devmode;
        my @found = sort {
                lc $a cmp lc $b
            }
            grep {
                !$current || /^$current/i
            }
            map {
                m{/([^/]+)$}; $1
            }
            $dir->children;
        print join "\n", @found, '';
    }
}

1;

__END__