File Coverage

blib/lib/Amon2/DBI.pm

Criterion	Covered	Total	%
statement	43	56	76.7
branch	8	22	36.3
condition	0	3	0.0
subroutine	13	16	81.2
pod	1	1	100.0
total	65	98	66.3

package Amon2::DBI;
use strict;
use warnings;
use 5.008001;
our $VERSION = '0.32';

use parent qw/DBI/;

sub connect {
    my ($class, $dsn, $user, $pass, $attr) = @_;
    $attr->{RaiseError} = 1;
    $attr->{PrintError} = 0;
    $attr->{ShowErrorStatement} = 1;
    if ($DBI::VERSION >= 1.614) {
        $attr->{AutoInactiveDestroy} = 1 unless exists $attr->{AutoInactiveDestroy};
    }
    if ($dsn =~ /^dbi:SQLite:/i) {
        $attr->{sqlite_unicode} = 1 unless exists $attr->{sqlite_unicode};
    }
    elsif ($dsn =~ /^dbi:mysql:/i) {
        $attr->{mysql_enable_utf8} = 1 unless exists $attr->{mysql_enable_utf8};
    }
    elsif ($dsn =~ /^dbi:Pg:/i) {
        my $dbd_pg_version = eval { require DBD::Pg; (DBD::Pg->VERSION =~ /^([.0-9]+)\./)[0] };
        if ( !$@ and $dbd_pg_version < 2.99 ) { # less than DBD::Pg 2.99, pg_enable_utf8 must be set for utf8.
            $attr->{pg_enable_utf8} = 1 unless exists $attr->{pg_enable_utf8};
        }
    }
    my $self = $class->SUPER::connect($dsn, $user, $pass, $attr) or die "Cannot connect to server: $DBI::errstr";
    return $self;
}

package Amon2::DBI::dr;
our @ISA = qw(DBI::dr);

package Amon2::DBI::db; # database handler
our @ISA = qw(DBI::db);

use DBIx::TransactionManager;
use SQL::Interp ();
use Carp ();
use Scalar::Util ();

sub connected {
    my $dbh = shift;
    $dbh->{private_connect_info} = [@_];
    $dbh->SUPER::connected(@_);
}

sub connect_info { $_[0]->{private_connect_info} }

sub _txn_manager {
    my $self = shift;
    if (not defined $self->{private_txn_manager}) {
        $self->{private_txn_manager} = DBIx::TransactionManager->new($self);
        Scalar::Util::weaken($self->{private_txn_manager}->{dbh});
    }
    return $self->{private_txn_manager};
}

sub txn_scope { $_[0]->_txn_manager->txn_scope(caller => [caller(0)]) }

sub do_i {
    my $self = shift;
    my ($sql, @bind) = SQL::Interp::sql_interp(@_);
    $self->do($sql, {}, @bind);
}

sub insert {
    my ($self, $table, $vars) = @_;
    $self->do_i("INSERT INTO $table", $vars);
}

package Amon2::DBI::st; # statement handler
our @ISA = qw(DBI::st);

sub sql { $_[0]->{private_sql} }

1;
__END__