File Coverage

lib/Amazon/SimpleDB/Item.pm

Criterion	Covered	Total	%
statement	7	9	77.7
branch			n/a
condition			n/a
subroutine	3	3	100.0
pod			n/a
total	10	12	83.3

package Amazon::SimpleDB::Item;
use strict;
use warnings;

use Amazon::SimpleDB::Response;
use Carp qw( croak );

sub new {
    my $class = shift;
    my $args  = shift || {};
    my $self  = bless $args, $class;
    croak "No account"     unless $self->{account};
    croak "No domain"      unless $self->{domain};
    croak "No (item) name" unless $self->{name};
    return $self;
}

sub account { return $_[0]->{account} }
sub name    { return $_[0]->{name} }
sub domain  { return $_[0]->{domain} }

sub get_attributes {
    my ($self, $name) = @_;
    my $params = {DomainName => $self->{domain}, ItemName => $self->{name}};
    $params->{AttributeName} = $name
      if defined $name;    # specific attribute request
    my $account = $self->{account};
    return
      Amazon::SimpleDB::Response->new(
                   http_response => $account->request('GetAttributes', $params),
                   domain        => $self,
                   account       => $self->{account},
      );
}

sub put_attributes {
    my ($self, $attr) = @_;
    my $params = _process_attribute_params($self, $attr);
    my $account = $self->{account};
    return
      Amazon::SimpleDB::Response->new(
                   http_response => $account->request('PutAttributes', $params),
                   domain        => $self,
                   account       => $self->{account},
      );
}

sub post_attributes {
    my ($self, $attr) = @_;
    my $params = _process_attribute_params($self, $attr, 1);
    my $account = $self->{account};
    return
      Amazon::SimpleDB::Response->new(
                   http_response => $account->request('PutAttributes', $params),
                   domain        => $self,
                   account       => $self->{account},
      );
}

sub delete_attributes {
    my ($self, $attr) = @_;
    my $params = _process_attribute_params($self, $attr);
    my $account = $self->{account};
    return
      Amazon::SimpleDB::Response->new(
                http_response => $account->request('DeleteAttributes', $params),
                domain        => $self,
                account       => $self->{account},
      );
}

#--- utility

sub _process_attribute_params {
    my ($self, $attr, $replace) = @_;
    my $params = {DomainName => $self->{domain}, ItemName => $self->{name}};
    return $params unless $attr;    # no attributes means the entire item.
    if (ref $attr eq 'HASH') {      # put/delete params with values.
        my $i = 0;
        for my $name (keys %$attr) {
            $attr->{$name} = [$attr->{$name}]
              unless ref $attr->{$name} eq 'ARRAY';
            for (@{$attr->{$name}}) {
                $params->{"Attribute.${i}.Name"}    = $name;
                $params->{"Attribute.${i}.Value"}   = $_;
                $params->{"Attribute.${i}.Replace"} = 'true'
                  if $replace;
                $i++;
            }
        }
    } elsif (ref $attr eq 'ARRAY') {    # delete multiple attributes, all values
        my $i = 0;
        for (@$attr) {
            $params->{"Attribute.${i}.Name"} = $_;
            $i++;
        }
    } else {                            # delete single attribute, all values
        $params->{AttributeName} = $attr;
    }
    return $params;
}

1;

__END__