File Coverage

blib/lib/Test/Alien/Diag.pm

Criterion	Covered	Total	%
statement	41	41	100.0
branch	9	10	90.0
condition			n/a
subroutine	6	6	100.0
pod	1	1	100.0
total	57	58	98.2

package Test::Alien::Diag;

use strict;
use warnings;
use 5.008004;
use Test2::API qw( context );
use Exporter qw( import );

our @EXPORT = qw( alien_diag );
our @EXPORT_OK = @EXPORT;

# ABSTRACT: Print out standard diagnostic for Aliens in the test step.
our $VERSION = '2.47'; # VERSION


sub alien_diag ($@)
{
  my $ctx = context();

  my $max = 0;
  foreach my $alien (@_)
  {
    foreach my $name (qw( cflags cflags_static libs libs_static version install_type dynamic_libs bin_dir ))
    {
      my $str = "$alien->$name";
      if(length($str) > $max)
      {
        $max = length($str);
      }
    }
  }


  $ctx->diag('');
  foreach my $alien (@_) {
    $ctx->diag('') for 1..2;

    my $found = 0;

    foreach my $name (qw( cflags cflags_static libs libs_static version install_type ))
    {
      if(eval { $alien->can($name) })
      {
        $found++;
        $ctx->diag(sprintf "%-${max}s = %s", "$alien->$name", $alien->$name);
      }
    }

    foreach my $name (qw( dynamic_libs bin_dir ))
    {
      if(eval { $alien->can($name) })
      {
        $found++;
        my @list = eval { $alien->$name };
        next if $@;
        $ctx->diag(sprintf "%-${max}s = %s", "$alien->$name", $_) for @list;
      }
    }

    $ctx->diag("no diagnostics found for $alien") unless $found;

    $ctx->diag('') for 1..2;
  }

  $ctx->release;
}

1;

__END__