File Coverage

blib/lib/Alien/Autotools.pm

Criterion	Covered	Total	%
statement	55	59	93.2
branch	6	12	50.0
condition			n/a
subroutine	16	20	80.0
pod	6	10	60.0
total	83	101	82.1

package Alien::Autotools;

use strict;
use warnings;
use base qw( Exporter );
use File::Which ();
use Path::Tiny  ();
use Alien::autoconf 0.18;
use Alien::automake 0.18;
use Alien::libtool  0.15;
use Alien::m4       0.18;

our @EXPORT_OK = qw(autoconf_dir automake_dir libtool_dir);

# ABSTRACT: Build and install the GNU build system.
our $VERSION = '1.07'; # VERSION


sub bin_dir
{
  my @dir = map { $_->bin_dir }
            map { "Alien::$_" }
            qw( autoconf automake libtool m4 );
  @dir;
}

sub _dir_from_exe
{
  my($name) = @_;
  my $path = File::Which::which($name);
  die "unable to find $name in PATH" unless $path;
  Path::Tiny->new($path)->parent->stringify;
}

my %helper;

sub alien_helper
{
  return \%helper if keys %helper;

  foreach my $alien ( map { "Alien::$_" } qw( autoconf automake libtool m4 ))
  {
    my %sub = %{ $alien->alien_helper };
    %helper = (%helper, %sub);
  }

  return \%helper;
}


sub aclocal_dir
{
  my @dir;
  foreach my $alien (map { "Alien::$_" } qw( autoconf automake libtool m4 ))
  {
    my $dir = Path::Tiny->new($alien->dist_dir)->child(qw( share aclocal ));
    push @dir, $dir if -d $dir;
  }
  @dir;
}


sub versions
{
  my %ver;
  foreach my $alien (qw( autoconf automake libtool m4 ))
  {
    my $class = "Alien::$alien";
    $ver{$alien} = $class->version;
  }
  %ver;
}


sub autoconf_dir ()
{
  my($dir) = Alien::autoconf->bin_dir;
  $dir
    ? $dir
    : _dir_from_exe('autoconf');
}


sub automake_dir ()
{
  my($dir) = Alien::automake->bin_dir;
  $dir
    ? $dir
    : _dir_from_exe('automake');
}


sub libtool_dir ()
{
  my($dir) = Alien::libtool->bin_dir;
  $dir
    ? $dir
    : _dir_from_exe('libtool');
}

sub cflags       {}
sub libs         {}
sub dynamic_libs {}

1;

__END__