File Coverage

blib/lib/Algorithm/Odometer/Tiny.pm

Criterion	Covered	Total	%
statement	37	37	100.0
branch	16	16	100.0
condition			n/a
subroutine	8	8	100.0
pod	0	2	0.0
total	61	63	96.8

#!perl
use warnings;
use strict;

# SEE THE END OF THIS FILE FOR AUTHOR, COPYRIGHT AND LICENSE INFORMATION

{ package Algorithm::Odometer::Tiny;
	our $VERSION = "0.04";
	use Carp;
	use overload '<>' => sub {
		my $self = shift;
		return $self->() unless wantarray;
		my @all;
		while (defined( my $x = $self->() ))
			{ push @all, $x }
		return @all;
	};
	sub new {  ## no critic (RequireArgUnpacking)
		my $class = shift;
		return bless odometer(@_), $class;
	}
	sub odometer {  ## no critic (RequireArgUnpacking)
		croak "no wheels specified" unless @_;
		my @w = map { [ 1, ref eq 'ARRAY' ? @$_ : $_ ] } @_;
		my $done;
		return sub {
			if ($done) { $done=0; return }
			my @cur = map {$$_[$$_[0]]} @w;
			for(my $i=$#w;$i>=0;$i--) {
				last if ++$w[$i][0]<@{$w[$i]};
				$w[$i][0]=1;
				$done=1 unless $i;
			}
			return wantarray ? @cur : join '', map {defined()?$_:''} @cur;
		};
	}
}

# Possible To-Do for Later: Generate regexes based on the wheels?

1;
__END__