File Coverage

blib/lib/AWS/CLI/Config.pm

Criterion	Covered	Total	%
statement	80	90	88.8
branch	21	30	70.0
condition	21	51	41.1
subroutine	20	23	86.9
pod	2	2	100.0
total	144	196	73.4

package AWS::CLI::Config;
use 5.008001;
use strict;
use warnings;

use Carp ();
use File::Spec;
use autodie;

our $VERSION = "0.04";

my $DEFAULT_PROFILE = 'default';

my $CREDENTIALS;
my %CREDENTIALS_PROFILE_OF;
my $CONFIG;
my %CONFIG_PROFILE_OF;

BEGIN: {
    my %accessor_of = (
        access_key_id     => +{ env => 'AWS_ACCESS_KEY_ID',     key => 'aws_access_key_id' },
        secret_access_key => +{ env => 'AWS_SECRET_ACCESS_KEY', key => 'aws_secret_access_key' },
        session_token     => +{ env => 'AWS_SESSION_TOKEN',     key => 'aws_session_token' },
        region            => +{ env => 'AWS_DEFAULT_REGION' },
        output            => +{},
    );

    MK_ACCESSOR: {
        no strict 'refs';
        for my $attr (keys %accessor_of) {
            my $func = __PACKAGE__ . "::$attr";
            *{$func} = _mk_accessor($attr, %{$accessor_of{$attr}});
        }
    }
}

sub _mk_accessor {
    my $attr = shift;
    my %opt  = @_;

    my $env_var = $opt{env};
    my $profile_key = $opt{key} || $attr;

    return sub {
        if ($env_var && exists $ENV{$env_var} && $ENV{$env_var}) {
            return $ENV{$env_var};
        }

        my $profile = shift || _default_profile();

        my $credentials = credentials($profile);
        if ($credentials && $credentials->$profile_key) {
            return $credentials->$profile_key;
        }

        my $config = config($profile);
        if ($config && $config->$profile_key) {
            return $config->$profile_key;
        }

        return undef;
    };
}

sub credentials {
    my $profile = shift || _default_profile();
    $CREDENTIALS ||= sub {
        my $path = File::Spec->catfile(_default_dir(), 'credentials');
        return +{} unless (-r $path);
        return _parse($path);
    }->();
    return unless (exists $CREDENTIALS->{$profile});
    $CREDENTIALS_PROFILE_OF{$profile} ||= AWS::CLI::Config::Profile->_new($CREDENTIALS->{$profile});
    return $CREDENTIALS_PROFILE_OF{$profile};
}

sub config {
    my $profile = shift || _default_profile();

    $CONFIG ||= sub {
        my $path
            = (exists $ENV{AWS_CONFIG_FILE} && $ENV{AWS_CONFIG_FILE})
            ? $ENV{AWS_CONFIG_FILE}
            : File::Spec->catfile(_default_dir(), 'config');
        return +{} unless (-r $path);

        return _parse($path);
    }->();

    return unless (exists $CONFIG->{$profile});
    $CONFIG_PROFILE_OF{$profile} ||= AWS::CLI::Config::Profile->_new($CONFIG->{$profile});
    return $CONFIG_PROFILE_OF{$profile};
}

sub _base_dir {
    ($^O eq 'MSWin32') ? $ENV{USERPROFILE} : $ENV{HOME};
}

sub _default_dir {
    File::Spec->catdir(_base_dir(), '.aws');
}

sub _default_profile {
    (exists $ENV{AWS_DEFAULT_PROFILE} && $ENV{AWS_DEFAULT_PROFILE})
        ? $ENV{AWS_DEFAULT_PROFILE}
        : $DEFAULT_PROFILE;
}

sub _parse {
  my $file = shift;
  my $profile = shift || _default_profile();

  my $hash = {};
  my $nested = {};

  my $contents;
  {
    local $/  = undef;
    open my $fh, '<', $file;
    $contents = <$fh>;
    close( $fh );
  }

  foreach my $line (split /\n/, $contents) {
    chomp $line;

    $profile = $1 if $line =~ /^\[(?:profile )?([\w]+)\]/;
    my ($indent, $key, $value) = $line =~ /^(\s*)([\w]+)\s*=\s*(.*)/;

    next if !defined $key or $key eq q{};

    if (length $indent) {
      $nested->{$key} = $value;
    }
    else {
      # Reset nested hash
      $nested = {} if keys %{$nested};
      $hash->{$profile}{$key} = ($key and $value) ? $value : $nested;
    }
  }

  return $hash;
}

PROFILE: {
    package AWS::CLI::Config::Profile;
    use 5.008001;
    use strict;
    use warnings;

    my @ACCESSORS;

    BEGIN {
        @ACCESSORS = qw(
            aws_access_key_id
            aws_secret_access_key
            aws_session_token
            region
            output
        );
    }

    use Object::Tiny @ACCESSORS;

    sub _new {
        my $class = shift;
        my $data  = shift;
        return bless $data, $class;
    }
}

1;
__END__